Script de sauvegarde d'un profil Firefox

Quand je disais qu'on peut tout faire en batch !

 Voici un script qui permet de sauvegarder le profil firefox de chaque utilisateur. Pour être efficace, mieux vaut le mettre en ouverture de session, donc mettre un raccouci de ce script dans "all users\démarrage", nécéssite seulement 7zip (installé dans C:\Program Files\7-Zip\ sinon changer le chemin dans le script)

@echo off
rem
echo Backup Firefox profile
echo http://superformance.blogspot.com
rem
set datapath=%~dp0data\
Set counterfile=%datapath%%username%.txt
set logpath=%~dp0%log\
set outputpath=%datapath%%username%\

if not exist %datapath% mkdir %datapath%
if not exist %logpath% mkdir %logpath%
if not exist %outputpath% mkdir %outputpath%
for /f "tokens=2,3 delims=/ " %%a in ('echo %date%') do set logfile=%logpath%%%b-%%a-%username%.log

call :Logadd "Debut de %~nx0"

set counter=0
if exist %counterfile% for /f %%a in ('type %counterfile%') do set counter=%%a
if %counter% LSS 0 set counter=0
if %counter% GTR 15 set counter=0

set /a counter=counter+1
echo %counter% > %counterfile%
set outputfile=%outputpath%%username%-profile-%counter%.zip
if exist %outputfile% del %outputfile%

call :Logadd "Archive N° %counter%"

set ffoxpath=%appdata%\Mozilla\firefox\
if not exist %ffoxpath% goto :eof
for /f "tokens=2 delims==" %%a in ('type %ffoxpath%profiles.ini ^| find /i "path"') do set ffprofile=%ffoxpath%%%a

call :Logadd "Creation de l'Archive %outputfile%"

if exist %outputfile% del %outputfile%

"C:\Program Files\7-Zip\7z.exe" a -tzip %outputfile% %ffprofile%\
if %errorlevel% NEQ 0 call :Logadd "Erreur dans la Creation de l'archive"

call :Logadd "Fin de %~nx0"

goto :eof

:Logadd
Echo %date% - %time% - %~1
Echo %date% - %time% - %~1 >> %logfile%
goto :eof